Άσκηση Αντι-ταξινόμησης..

Ξεκίνησε από Sergio, 02 Μαρ 2011, 11:00:44 ΠΜ

« προηγούμενο - επόμενο »

Sergio

Να κατασκευάσετε αλγόριθμο που θα ταξινομεί τα Ν στοιχεία ενός πίνακα Π σε αύξουσα σειρά και μετά θα επαναφέρει τα στοιχεία του πίνακα στις αρχικές τους θέσεις. 

Ένα "φτηνό κόλπο" είναι να δημιουργείται, πριν την ταξινόμηση, ένα αντίγραφο του πίνακα Π οπότε, μετά την ταξινόμηση, το μόνο που χρειάζεται είναι να αντιγράφονται τα στοιχεία από το αντίγραφο, στον αρχικό πίνακα.

Να δώσετε λύση που ΔΕΝ θα χρησιμοποιεί αυτό το "φτηνό κόλπο" ;)



Παραθέτω στη συνέχεια την απάντηση, όπως αυτή διαμορφώθηκε μετά τη συζήτηση που έγινε.  Για όποιον ενδιαφέρεται, η συζήτηση ακολουθεί..



Προτάθηκαν 3 λύσεις:

1. καταγραφή αρχικών θέσεων και επαναφορά με νέα ταξινόμηση και κριτήριο τις αρχικές θέσεις
2. καταγραφή ιστορικού αντιμεταθέσεων και επαναφορά με ανάστροφη εφαρμογή τους (undo)
3. καταγραφή αρχικών θέσεων και επαναφορά με επανατοποθέτηση στις αρχικές θέσεις (αλυσιδωτά)

Αναλυτικά:



Λύση 1
α. πριν γίνει η ταξινόμηση των στοιχείων δημιουργείται νέος παράλληλος πίνακας στον οποίο καταχωρίζονται οι αρχικές θέσεις των στοιχείων (θ[ι] <- ι)
β. ακολουθεί η ταξινόμηση των δύο παράλληλων πινάκων (Π, Θ) με κριτήριο τις τιμές του πίνακα δεδομένων (Π)
γ. γίνεται εκ νέου ταξινόμηση των δύο παράλληλων πινάκων (Π, Θ) με κριτήριο τις τιμές του πίνακα θέσεων (Π) οπότε οι τιμές του παράλληλου πίνακα επανέρχονται στις αρχικές τους θέσεις

Αλγόριθμος Ταξινόμηση_και_επαναφορά_1
Δεδομένα //Π, Ν//

! δημιουργία πίνακα θέσεων
!------------------------------
ΓΙΑ δ ΑΠΟ 1 ΜΕΧΡΙ Ν
  Θ[δ] ←  δ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! ταξινόμηση με κριτήριο τα στοιχεία του Π
!-----------------------------------------------
Για ι από 2 μέχρι Ν
	Για ξ από Ν μέχρι ι με_βήμα -1
		Αν Π[ξ] < Π[ξ-1] τότε
			Αντιμετάθεσε Π[ξ], Π[ξ-1]
			Αντιμετάθεσε Θ[ξ], Θ[ξ-1]
		Τέλος_αν
	Τέλος_επανάληψης
Τέλος_επανάληψης

! επαναφορά (ταξινόμηση με κριτήριο τα στοιχεία του Θ)
!--------------------------------------------------------------
Για ι από 2 μέχρι Ν
	Για ξ από Ν μέχρι ι με_βήμα -1	
		Αν Θ[ξ] < Θ[ξ-1] τότε
			Αντιμετάθεσε Π[ξ], Π[ξ-1]
			Αντιμετάθεσε Θ[ξ], Θ[ξ-1]
		Τέλος_αν
	Τέλος_επανάληψης
Τέλος_επανάληψης

Αποτελέσματα //Π//
Τέλος Ταξινόμηση_και_επαναφορά_1


Λύση 2
α. κατά την ταξινόμηση των στοιχείων του πίνακα, κάθε φορά που γίνεται μία αντιμετάθεση, καταχωρίζεται σε νέο πίνακα (που λειτουργεί ως στοίβα) η θέση του στοιχείου που αντιμετατέθηκε, καταγράφοντας έτσι το ιστορικό των αντιμεταθέσεων που έγιναν
β. μετά την ταξινόμηση, οι αντιμεταθέσεις γίνονται ξανά, αλλά με την αντίστροφη σειρά, υλοποιώντας την ακριβώς αντίστροφη διαδικασία, οπότε ο πίνακας επαναφέρεται στην αρχική του κατάσταση

Πρόκειται ουσιαστικά με υλοποίηση της λειτουργίας undo, βήμα-προς-βήμα στη διαδικασία ταξινόμησης

Αλγόριθμος Ταξινόμηση_και_επαναφορά_2
Δεδομένα //Π, Ν//

! ταξινόμηση με καταγραφή ιστορικού αντιμεταθέσεων
!--------------------------------------------------------------
μ ← 0
Για ι από 2 μέχρι Ν
	Για ξ από Ν μέχρι ι με_βήμα -1
		Αν Π[ξ] < Π[ξ-1] τότε
			Αντιμετάθεσε Π[ξ], Π[ξ-1]
			μ ← μ + 1
			Α[μ] ← ξ      ! καταγράφηκε
		Τέλος_αν
	Τέλος_επανάληψης
Τέλος_επανάληψης

! επαναφορά (επανάληψη των αντιμεταθέσεων, με ανάποδη σειρά - UNDO)
!-----------------------------------------------------------------------------------
Για ι από μ μέχρι 1 με_βήμα -1
	Αντιμετάθεσε Π[Α[ι]], Π[Α[ι]-1]
Τέλος_επανάληψης

Αποτελέσματα //Π//
Τέλος  Ταξινόμηση_και_επαναφορά_2


Λύση 3
α. πριν γίνει η ταξινόμηση των στοιχείων δημιουργείται νέος παράλληλος πίνακας στον οποίο καταχωρίζονται οι αρχικές θέσεις των στοιχείων (θ[ι] <- ι)
β. ακολουθεί η ταξινόμηση των δύο παράλληλων πινάκων (Π, Θ) με κριτήριο τις τιμές του πίνακα δεδομένων (Π)
γ. με ένα πέρασμα του πίνακα των θέσεων, εφαρμόζεται μια διαδικασία αλυσιδωτής αναδιάταξης των στοιχείων, ώστε να επανέλθουν στις αρχικές τους θέσεις, ως εξής:
  - το πρώτο στοιχείο του πίνακα αντιμετατίθεται με εκείνο που βρίσκεται στη θέση του. Έτσι, το πρώτο πηγαίνει στη σωστή του θέση και στην πρώτη θέση έρχεται εκείνο που την καταλάμβανε.
  - το στοιχείο που ήρθε στην πρώτη θέση εξετάζεται πάλι, αφού ενδέχεται να "ανήκει" σε άλλη θέση.
  - η διαδικασία επαναλαμβάνεται με την ίδια θέση μέχρι, κάποια στιγμή, να έρθει στη θέση αυτή το στοιχείο που πρέπει
  - η διαδικασία συνεχίζεται όμοια με την επόμενη θέση του πίνακα, μέχρι να εξαντληθούν όλες οι θέσεις
Επειδή η αλυσιδωτή αυτή τακτοποίηση ενδέχεται να διατάξει τα στοιχεία σωστά ΠΡΙΝ φτάσει στο τέλος του πίνακα, η εξέταση - επανατοποθέτηση του στοιχείου (αρχή της αλυσίδας) γίνεται μόνον εάν δεν είναι ήδη στη σωστή του θέση

Αλγόριθμος Ταξινόμηση_και_επαναφορά_3
Δεδομένα //Π, Ν//

! δημιουργία πίνακα θέσεων
!------------------------------
ΓΙΑ δ ΑΠΟ 1 ΜΕΧΡΙ Ν
  Θ[δ] ←  δ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! Ταξινόμηση
!------------------------------
Για ι από 2 μέχρι Ν
	Για ξ από Ν μέχρι ι με_βήμα -1
		Αν Π[ξ] < Π[ξ-1] τότε
			Αντιμετάθεσε Π[ξ], Π[ξ-1]
			Αντιμετάθεσε Θ[ξ], Θ[ξ-1]
		Τέλος_αν
	Τέλος_επανάληψης
Τέλος_επανάληψης

! επαναφορά με βάση τις αρχικές θέσεις
!-------------------------------------------
ΓΙΑ δ ΑΠΟ 1 ΜΕΧΡΙ Ν-1
  ΟΣΟ Θ[δ] <> δ ΕΠΑΝΑΛΑΒΕ     ! αλυσιδωτά
    αρχική ←  Θ[δ]
    αντιμετάθεσε Π[δ], Π[αρχική]
    αντιμετάθεσε Θ[δ], Θ[αρχική]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

Αποτελέσματα //Π//
Τέλος Ταξινόμηση_και_επαναφορά_3


Συμπερασματικά



Η λύση 1 φαίνεται να είναι η πιό απλή στην υλοποίηση, είναι όμως η πιό αργή απ'όλες
Η λύση 2 είναι πιό εμπνευσμένη, πιό γρήγορη, αλλά πιό δύσκολη στη σύλληψη αν και αποδεικνύεται αρκετά απλή στην υλοποίηση
Η λύση 3 είναι η πιό γρήγορη απ'όλες, αλλά ακόμα πιό δύσκολη στη σύλληψη και στην υλοποίηση, ιδιαίτερα στο κομμάτι που αφορά στην αλυσιδωτή επαναφορά
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

sstergou

Άλλο "φτηνό" κόλπο επιτρέπεται να χρησιμοποιήσουμε;

Κώδικας: Ψευδογλώσσα
Αλγόριθμος τάδε

Δεδομένα //Π, Ν//

μ ← 0

Για ι από 2 μέχρι Ν
	Για ξ από Ν μέχρι ι με_βήμα -1
		Αν Π[ξ] < Π[ξ-1] τότε
			Αντιμετάθεσε Π[ξ], Π[ξ-1]
			μ ← μ + 1
			Α[μ] ← ξ - 1
		Τέλος_αν
	Τέλος_επανάληψης
Τέλος_επανάληψης

Για ι από μ μέχρι 1 με_βήμα -1
	Αντιμετάθεσε Π[Α[ι]], Π[Α[ι] + 1]
Τέλος_επανάληψης

Αποτελέσματα //Π//


Τέλος τάδε



Και κάνω μια ρητορική ερώτηση : "Είναι σωστή αυτή η λύση;"

Sergio

την.. δοκίμασες στο pseudoglossa.gr ;;  Είναι ένα βολικό περιβάλλον στο οποίο μπορείς να δοκιμάζεις τις λύσεις σου  ;D ;D :P
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

sstergou

χεχε :)

Όσον αφορά την λύση αυτό που γίνεται είναι το εξής (το γράφω για κάθε ενδιαφερόμενο) :
Κρατάμε σε έναν πίνακα (που μοιάζει με στοίβα) το ιστορικό των αντιμεταθέσεων. Μετά την ταξινόμηση διασχίζουμε τον πίνακα από το τέλος προς την αρχή και κάνουμε κάτι σαν "undo" για κάθε αντιμετάθεση.

sstergou

Σέργιε η ρητορική ερώτηση αφορούσε το αν μπορούμε να χρησιμοποιήσουμε τον πίνακα Α.

soron80

Παράθεση από: sstergou στις 02 Μαρ 2011, 06:29:03 ΜΜ
Σέργιε η ρητορική ερώτηση αφορούσε το αν μπορούμε να χρησιμοποιήσουμε τον πίνακα Α.

κι εγώ αυτή την απορία έχω..
π.χ. μπορούμε να χρησιμοποιήσουμε πίνακα Α με τις παλιές θέσεις των στοιχείων?
Τσισπαράς Βασίλης
Καθηγητής Πληροφορικής ΠΕ19

Sergio

Παράθεση από: sstergou στις 02 Μαρ 2011, 06:29:03 ΜΜ
Σέργιε η ρητορική ερώτηση αφορούσε το αν μπορούμε να χρησιμοποιήσουμε τον πίνακα Α.

ΑΣΦΑΛΩΣ και μπορούμε.. Μπορούμε να κάνουμε Ο,ΤΙ θέλουμε.. Αρκεί να μπορεί να γίνει..

Μόνο το φτηνό κόλπο δε μπορούμε να κάνουμε.. (στο πλαίσιο της εκφώνησης πάντα..) Και αυτό γιατί έτσι, ευτελίζουμε την άσκηση ;)
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

pgrontas

Ο Στάθης ανοίγει πληγές :D. Αν και δεν έχω κοιτάξει τον αλγόριθμο με λεπτομέρεια, αλλά διακινδυνεύω να πω ότι εφόσον μπορούμε να υπολογίσουμε εκ των προτέρων μία εύλογη χειρότερη περίπτωση για το πλήθος των αντιμεταθέσεων (και όχι να το διαβάσουμε από τον χρήστη) τότε ναι μπορούμε :) :-X
Programs must be written for people to read, and only incidentally for machines to execute - Harold Abelson

Sergio

Παράθεση από: soron80 στις 02 Μαρ 2011, 09:14:28 ΜΜ
κι εγώ αυτή την απορία έχω..
π.χ. μπορούμε να χρησιμοποιήσουμε πίνακα Α με τις παλιές θέσεις των στοιχείων?

Μπορούμε να κάνουμε Ο,ΤΙ θέλουμε.. Αρκεί να μπορεί να γίνει.. (βέβαια στον A, o Στάθης κρατάει ιστορικό αντιμεταθέσεων προκειμένου να κάνει undo..)
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

Sergio

Παράθεση από: sstergou στις 02 Μαρ 2011, 06:00:24 ΜΜ
Κρατάμε σε έναν πίνακα (που μοιάζει με στοίβα) το ιστορικό των αντιμεταθέσεων. Μετά την ταξινόμηση διασχίζουμε τον πίνακα από το τέλος προς την αρχή και κάνουμε κάτι σαν "undo" για κάθε αντιμετάθεση.

Η λύση του Στάθη είναι μια ομορφιά .. (προσωπική άποψη)..
Παράθεση από: pgrontas στις 02 Μαρ 2011, 09:38:24 ΜΜ
Ο Στάθης ανοίγει πληγές :D. Αν και δεν έχω κοιτάξει τον αλγόριθμο με λεπτομέρεια, αλλά διακινδυνεύω να πω ότι εφόσον μπορούμε να υπολογίσουμε εκ των προτέρων μία εύλογη χειρότερη περίπτωση για το πλήθος των αντιμεταθέσεων (και όχι να το διαβάσουμε από τον χρήστη) τότε ναι μπορούμε :) :-X

Αμάν βρε Παναγιώτη.. Όλα να τα μαρτυρήσεις και συ.. >:D :P :'(

Ότι ετοιμαζόμουν να ποστάρω το παρακάτω:




Να μεταφέρετε τον αλγόριθμο του Στάθη σε πρόγραμμα, ξεκινώντας όπως δίνεται στη συνέχεια:

Πρόγραμμα Ταξινόμηση_και_μετά_UNDO
Σταθερές
   Ν = 100
.
.


Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

sstergou

Το μέγεθος του πίνακα εξαρτάται από την πολυπλοκότητα της φυσαλίδας. Είναι ένας όμορφος τρόπος να εισάγεις αυτή την έννοια (αν ήταν μέσα στην ύλη βέβαια.)

odysseas

Δημιουργούμε τον παρακάτω πίνακα Θ, κάθε στοιχείο του οποίου είναι ίσο με το δείκτη του. Πρακτικά πρόκειται για την αρχική θέση κάθε στοιχείου.

ΓΙΑ δ ΑΠΟ 1 ΜΕΧΡΙ Ν
  Θ[δ] <- δ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


Ταξινομούμε τον πίνακα Π παράλληλα με τον πίνακα Θ. Μετά την ταξινόμηση, το στοιχείο Θ[δ] περιέχει την αρχική θέση του Π[δ].

! μεταφορά στην αρχική θέση
ΓΙΑ δ ΑΠΟ 1 ΜΕΧΡΙ Ν-1
  αρχική <- Θ[δ]
  αντιμετάθεσε Π[δ], Π[αρχική]
  αντιμετάθεσε Θ[δ], Θ[αρχική]
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


Συνήθης πρακτική είναι επίσης να ταξινομείται μόνο ο πίνακας Θ και όχι ο πίνακας δεδομένων.

Sergio

Παράθεση από: sstergou στις 02 Μαρ 2011, 09:54:09 ΜΜ
Το μέγεθος του πίνακα εξαρτάται από την πολυπλοκότητα της φυσαλίδας. Είναι ένας όμορφος τρόπος να εισάγεις αυτή την έννοια (αν ήταν μέσα στην ύλη βέβαια.)

Ακριβώς.. και αφού στο πλαίσιο του μαθήματος ασχολούμαστε με στατικούς πίνακες, των οποίων το μέγεθος πρέπει να είναι γνωστό κατά τη στιγμή του προγραμματισμού, θα πρέπει είναι γνωστός, αν όχι ο ακριβής, έστω ο μεγαλύτερος αριθμός στοιχείων που μπορεί να έχει ο πίνακας

Στην ταξινόμηση φυσαλίδας, ο μεγαλύτερος αριθμός αντιμεταθέσεων γίνεται όταν τα στοιχεία έχουν ακριβώς αντίθετη διάταξη από την επιθυμητή.. (και αυτό είναι στο πλαίσο του μαθήματος :) )  Σε αυτή την περίπτωση, κάθε σύγκριση οδηγεί σε αντιμετάθεση..  Επομένως το πρόβλημα (του υπολογισμού του μέγιστου αριθμού θέσεων του πίνακα) ανάγεται σε πρόβλημα μέτρησης του αριθμού των συγκρίσεων δηλαδή ουσιαστικά σε μέτρηση του πλήθους των επαναλήψεων:

Οι επαναλήψεις είναι Ν-1 την πρώτη φορά, Ν-2 τη δεύτερη, Ν-3 την τρίτη, κ.ο.κ. και την τελευταία φορά μόνο 1.. Οι "φορές" είναι Ν-1 (Για ι από 2 μέχρι Ν), επομένως οι επαναλήψεις είναι:
1) Ν-1
2) Ν-2
3) Ν-3
.
.
Ν-1) 1

Το άθροισμα αυτής της σειράς είναι, αν θυμάμαι καλά) Ν * (Ν - 1) / 2.. Επομένως στην περίπτωσή μας: 100*99/2 = 4500.

Συνεπώς, το πρόγραμμα θα μπορούσε να έχει τη μορφή:

Πρόγραμμα Ταξινόμηση_και_μετά_UNDO
Σταθερές
   Ν = 100
   Μ = 4500
ΜΕΤΑΒΛΗΤΕΣ
   ΑΚΕΡΑΙΕΣ: Π[100], Α[4500]
.
.


Οπότε ο αλγόριθμος του Στάθη, μεταφέρεται μιααα χααααρά σε πρόγραμμα :)
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

Sergio

Παράθεση από: odysseas στις 03 Μαρ 2011, 01:17:13 ΠΜ
Δημιουργούμε τον παρακάτω πίνακα Θ, κάθε στοιχείο του οποίου είναι ίσο με το δείκτη του. Πρακτικά πρόκειται για την αρχική θέση κάθε στοιχείου.
...
Ταξινομούμε τον πίνακα Π παράλληλα με τον πίνακα Θ. Μετά την ταξινόμηση, το στοιχείο Θ[δ] περιέχει την αρχική θέση του Π[δ].
...

Επίσης πολύ κομψή λύση, με μικρότερες απαιτήσεις σε μνήμη και .. ταχύτερη "επαναφορά" των στοιχείων στις αρχικές τους θέσεις αφού αυτή γίνεται με μονή επανάληψη (τάξης Ν) και όχι διπλή (τάξης Ν2)
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)

Sergio

Ένας ακόμη τρόπος επαναφοράς των στοιχείων στην αρχική τους θέση, πιό κοντά στο σκεπτικό του Οδυσσέα, είναι:
1. να δημιουργηθεί ο πίνακας των θέσεων ΠΡΙΝ την ταξινόμηση
2. να "ακολουθούν" οι δείκτες τα στοιχεία κατά την αντιμετάθεση και
3. για την επαναφορά, να γίνεται ξανά ταξινόμηση με κριτήριο, αυτή τη φορά, τους δείκτες.. και να "ακολουθούν" τα στοιχεία..  Έτσι, θα επιστρέψουν στις αρχικές τους θέσεις.

Ίδιες απαιτήσεις σε μνήμη με τον τρόπο του Οδυσσέα, αλλά πιό αργός (τάξης Ν2). Νομίζω όμως, ευκολότερος στην υλοποίηση (για τους μαθητές).
Απ τη μια η θητεία μου σε σχολικές αίθουσες: να φλυαρώ - να ελπίζω πως κατι κατάλαβαν - να εξερευνώ - να μαθαίνω. Απ την άλλη, σχεδόν συνομήλικη, η Διδακτική της Πληροφορικής: ερευνά διαδικασίες μάθησης - φλερτάρει με την Ψυχολογία - με καλεί να αφήσω το βλέμμα του Πληροφορικού και να δω με τα μάτια του δασκάλου. Τέκνα των 2, οι απόψεις μου.. (προσαρμοσμένο από τον πρόλογο του βιβλίου "Το μακρόν Φυσική προ του βραχέως διδάσκω" του Ανδρέα Κασσέτα)